Making Password Protected PDFs using Excel Vba and PDFtk Tool

Hi Everyone,

This time, I have come up a VBA Code to generate Password protected PDFs using Excel. Actually, Excel Vba has .ExportAsFixedFormat Method to generate PDFs but this hasn't any Parameter which takes password to protect the PDFs. So I have used PDFtk Tool which provide Command Line Interface to make PDFs protected using Password. Actually, You can do various things using PDFtk Tool command line varying from creating, merging, Protecting and many other. So Download the PDFtk Tool from the following link:-

Download PDFtk Tookit

Here are the Steps:-

1. Install the PDFtk Toolkit.

2. Use the following code to Print or Export the Activesheet with a password.

       
Sub PasswordProtectedPDFs()

    Application.ScreenUpdating = False
    Application.DisplayAlerts = False

    Dim fTemp As String                                   'Defining Variables
    Dim oPdf As String
    Dim Pwd As String
    
    fTemp = ThisWorkbook.Path & "\" & "Temp.Pdf"          'Full path for temporary file.
    oPdf = "D:\ProtectedPDF.Pdf"                          'Set Path and Name for Protected Output PDF here.
    Pwd = "vikas"                                         'Set appropriate Password here.
    
    With ActiveSheet                                      'Making a Temporary Unprotected Pdf file.
       .ExportAsFixedFormat Type:=xlTypePDF, _
                            Filename:=fTemp, _
                            Quality:=xlQualityStandard
    End With
    
    fTemp = """" & fTemp & """"                           'Putting extra "" around for command Parameter.
    oPdf = """" & oPdf & """"
    Pwd = """" & Pwd & """"
                                                          'Making Command String for making protected PDFs Using PDFtk tool.
    cmdStr = "pdftk " & fTemp _
                      & " Output " & oPdf _
                      & " User_pw " & Pwd _
                      & " Allow AllFeatures"

    Shell cmdStr, vbHide                                  'Executing PDFtk Command.
    
    Application.Wait DateAdd("s", 2, Now)                 'Allowing 2 secs for command to execute.
    
    Kill Replace(fTemp, """", "")                         'Deleting temporary files.
    
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
    
    MsgBox "Finished", vbInformation
    
End Sub 

Here is the link where you can see its application:-

http://www.excelforum.com/excel-programming-vba-macros/1069367-making-password-protected-pdfs-using-excel-vba-and-pdftk-tool.html

Remarks:-
You can do many more things using excel vba and PDFtk tool Command line interface. Here is the link where you can see many PDFtk functions and its command line parameters.
PDFtk Command Line Manual

Regards,
Vikas Gautam